Revista do CD-ROM 101/CD-ROM 101.iso/compl/maya5ple/Install_MayaPLE5_English.exe/Maya/Data1.cab/performWireParentBase.mel

Text File | 2003-07-17 | 9.4 KB | 380 lines

// Copyright (C) 1997-2002 Alias|Wavefront,
// a division of Silicon Graphics Limited.
//
// The information in this file is provided for the exclusive use of the
// licensees of Alias|Wavefront.  Such users have the right to use, modify,
// and incorporate this code into other products for purposes authorized
// by the Alias|Wavefront license agreement, without fee.
//
// ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
// EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
// CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
// DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
// TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
// PERFORMANCE OF THIS SOFTWARE.
//
//
//  Alias|Wavefront Script File
//  MODIFY THIS AT YOUR OWN RISK
//
//  Creation Date:  24 April 1997
//
//  Description:
//    This script provides an option box dialog for the wireParentBase command.
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//        Initialize the option values.
//
//  Input Arguments:
//        Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
    //    No option vars since users have indicated that it does not make
    // sense for the node name to persist as a pref
    //
}

//
//  Procedure Name:
//      wireParentBaseSetup
//
//  Description:
//        Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be
//                             successfully resolved.
//
//    forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc wireParentBaseSetup(string $parent, int $forceFactorySettings)
{
    // Retrieve the option settings
    //
    setOptionVars ($forceFactorySettings);

    setParent $parent;

    // Query the optionVar's and set the values into the controls

    checkBoxGrp -edit -v1 0 wrSpec;
    textFieldGrp -e -tx "" -enable 0 wrNode;
    optionMenuGrp -e -enable 0 wrList;
}

//
//  Procedure Name:
//      wireParentBaseCallback
//
//  Description:
//        Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//    doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc wireParentBaseCallback(string $parent, int $doIt)
{
    setParent $parent;

    // Set the optionVar's from the control values, and then perform the
    // command
    if ($doIt) {
        performWireParentBase 0;
        addToRecentCommandQueue "performWireParentBase 0" "Wire Parent Base";
    }
}

//
//  Procedure Name:
//      wireParentBaseOptions
//
//  Description:
//        Construct the option box UI.  Involves accessing the standard option
//        box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc wireParentBaseOptions()
{
    //    Name of the command for this option box.
    //
    string $commandName = "wireParentBase";

    //    Build the option box actions.
    //
    string $callback = ($commandName + "Callback");
    string $setup = ($commandName + "Setup");

    //    STEP 1:  Get the option box.
    //    ============================
    //
    //    The value returned is the name of the layout to be used as
    //    the parent for the option box UI.
    //
    string $layout = getOptionBox();
    setParent $layout;

    //    STEP 2:  Pass the command name to the option box.
    //    =================================================
    //
    //    Any default option box behaviour based on the command name is set
    //    up with this call.  For example, updating the 'Help' menu item with
    //    the name of the command.
    //
    setOptionBoxCommandName("wire");

    //    STEP 3:  Activate the default UI template.
    //    ==========================================
    //
    //    Activate the default UI template so that the layout of this
    //    option box is consistent with the layout of the rest of the
    //    application.
    //
    setUITemplate -pushTemplate DefaultTemplate;

    //    STEP 4: Create option box contents.
    //    ===================================
    //
    //    This, of course, will vary from option box to option box.

    //    Turn on the wait cursor.
    //
    waitCursor -state 1;

    tabLayout -tabsVisible 0 -scrollable 1;

    string $parent = `columnLayout -adjustableColumn 1`;

    checkBoxGrp
        -numberOfCheckBoxes 1
        -label "Specify Node"
        -label1 ""
        -v1 0
        -on1 "optionMenuGrp -e -enable 1 wrList;textFieldGrp -e -enable 1 wrNode"
         -offCommand "optionMenuGrp -e -enable 0 wrList;textFieldGrp -e -enable 0 wrNode"
        wrSpec;

    textFieldGrp -enable 0 -label "Wire Node" -tx "" wrNode;
    // Create an option menu listing existing wires
    //
    optionMenuGrp -enable 0 -l "Existing Nodes"
        -cc "textFieldGrp -e -tx `optionMenuGrp -q -v wrList` wrNode" wrList;

    // add all the wires to the menu
    //
    int $pp;
    string $bnArray[];
    $bnArray = `ls -type wire`;
    int $bnCount = size($bnArray);
    if ($bnCount > 0 ) {
        for ($pp = 0; $pp < $bnCount; $pp++)
        {
            menuItem -l $bnArray[$pp];
        }
    } else {
        menuItem -l "No Wires Selected";
    }

    //    Turn off the wait cursor.
    //
    waitCursor -state 0;

    //    Step 5: Deactivate the default UI template.
    //    ===========================================
    //
    setUITemplate -popTemplate;

    //    Step 6: Customize the buttons.
    //    ==============================
    //
    //    Provide more descriptive labels for the buttons.  This is not
    //    necessary, but in some cases, for example, a button labelled
    //    'Create' may be more meaningful to the user than one labelled
    //    'Apply'.
    //
    //    Disable those buttons that are not applicable to the option box.
    //
    //    Attach actions to those buttons that are applicable to the option
    //    box.  Note that the 'Close' button has a default action attached
    //    to it that will hide the window.  If a a custom action is
    //    attached to the 'Close' button then be sure to call the 'hide the
    //    option box' procedure within the custom action so that the option
    //    box is hidden properly.

    //    'Apply' button.
    //
    string $applyBtn = getOptionBoxApplyBtn();
    button -edit
        -command ($callback + " " + $parent + " " + 1)
        $applyBtn;

    //    'Save' button.
    //
    string $saveBtn = getOptionBoxSaveBtn();
    button -edit
        -command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
        $saveBtn;

    //    'Reset' button.
    //
    string $resetBtn = getOptionBoxResetBtn();
    button -edit
        -command ($setup + " " + $parent + " " + 1)
        $resetBtn;

    //    Step 7: Set the option box title.
    //    =================================
    //
    setOptionBoxTitle("Parent Base Wire Options");

    //    Step 8: Customize the 'Help' menu item text.
    //    ============================================
    //
    setOptionBoxHelpTag( "ParentBaseWire" );

    //    Step 9: Set the current values of the option box.
    //    =================================================
    //
    eval (($setup + " " + $parent + " " + 0));

    //    Step 10: Show the option box.
    //    =============================
    //
    showOptionBox();
}

//
//  Procedure Name:
//      wireParentBaseHelp
//
//  Description:
//        Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string wireParentBaseHelp()
{

    return
    "  Command: wireParentBase";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//        Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
    string $cmd;

    setOptionVars(false);

    $cmd = "doWireEdit";

    //    This is parent base wire mode = 5

    int $radio = 5;

    int $wrp=0;
    if (`checkBoxGrp -exists wrSpec`) {
        $wrp = `checkBoxGrp -query -v1 wrSpec`;
    }

    string $wrn="\"\"";
    if (`textFieldGrp -exists wrNode`) {
        $wrn=`textFieldGrp -query -tx wrNode`;
        if ($wrn=="") $wrn="\"\"";
    }

    $cmd += (" " + $radio + " " + $wrp + " " + $wrn);
    return $cmd;
}

//
//  Procedure Name:
//      performWireParentBase
//
//  Description:
//        Perform the wireParentBase command using the corresponding
//        option values.  This procedure will also show the option box
//        window if necessary as well as construct the command string
//        that will invoke the wireParentBase command with the current
//        option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performWireParentBase(int $action)
{
    string $cmd = "";

    switch ($action) {

        //    Execute the command.
        //
        case 0:
            //    Get the command.
            //
            $cmd = `assembleCmd`;

            //    Execute the command with the option settings.
            //
            eval($cmd);

            break;

        //    Show the option box.
        //
        case 1:
            wireParentBaseOptions;
            break;

        //    Return the command string.
        //
        case 2:
            //    Get the command.
            //
            $cmd = `assembleCmd`;
            break;
    }
    return $cmd;
}